Go Back   EQEmulator Home > EQEmulator Forums > General > General::General Discussion

General::General Discussion General discussion about EverQuest(tm), EQEMu, and related topics.
Do not post support topics here.

Reply
 
Thread Tools Display Modes
  #1  
Old 07-15-2009, 12:17 PM
vales
Discordant
 
Join Date: May 2006
Posts: 458
Default

They should really go after those people who got Horde tattoos then and skin them.
Reply With Quote
  #2  
Old 07-16-2009, 06:37 PM
Pyrocat22259
Fire Beetle
 
Join Date: Mar 2006
Posts: 7
Default

So is there any way to make it select a random one every time you load or do you just pick your favorite?
Reply With Quote
  #3  
Old 07-16-2009, 07:11 PM
Shendare
Dragon
 
Join Date: Apr 2009
Location: California
Posts: 814
Default

One way to have the loading screen randomly selected when you start the game would be to load with a batch file like the following.

Note 1: You would need to change your EQ shortcut from pointing to "eqgame.exe patchme" to pointing to your new batchfile.

Note 2: This batch file's coding assumes you have installed your load*.jpg files into a folder called "Loadscreens" inside the "Resources" folder of your EverQuest directory.

File: eqgame.bat
Code:
@Echo Off

Title EverQuest Loader

If Not Exist Resources\Loadscreens\load*.jpg GoTo :NotHere

PushD Resources
If Not Exist loadscreen.jpg.backup If Exist loadscreen.jpg Copy /Y loadscreen.jpg loadscreen.jpg.backup > nul

PushD Loadscreens

Del ..\loadscreen.jpg

:AddLoadscreen
For %%F In (load*.jpg) Do Call :CheckLoadscreen %%F
If Not Exist ..\loadscreen.jpg GoTo :AddLoadscreen

PopD

PopD

Echo Starting EverQuest...

Start /Wait eqgame.exe patchme

PushD Resources
If Exist loadscreen.jpg.backup Copy /Y loadscreen.jpg.backup loadscreen.jpg > nul
PopD

GoTo :EOF

:NotHere
Echo .\Resources\Loadscreens\load*.jpg not found. Make sure you are loading from the EQ directory and have the load screens installed.
GoTo :EOF

:CheckLoadscreen
If /I %Random% LSS 1000 Copy /Y %1 ..\loadscreen.jpg > nul
GoTo :EOF
Tested and working on Windows XP. Should work just as well on Vista.

If you're using Vista, though, make sure you're working in a directory you have Write permissions in, or have the batch file set to Run as Administrator, or it won't be able to copy the files around as it needs to.
Reply With Quote
  #4  
Old 07-17-2009, 04:38 PM
vales
Discordant
 
Join Date: May 2006
Posts: 458
Default

Awesome. Thanks for that Shendare.

I'll pack it in with the next batch I upload. That is, if it's okay with you.
Reply With Quote
  #5  
Old 07-17-2009, 04:49 PM
Shendare
Dragon
 
Join Date: Apr 2009
Location: California
Posts: 814
Default

Feel free. I just threw it together after refreshing my memory on a few DOS commands.

If anyone's concerned about how exactly it works, these are the steps:

1. Verifies that it can see Resources\Loadscreens\load*.jpg

2. Makes sure there's a backup of your original Resources\loadscreen.jpg

3. Runs through the list of files in Resources\Loadscreens to randomly pick one to copy as your loadscreen.

4. Starts EQ and waits for it to finish

5. Restores your original loadscreen from the backup in #2

The way it randomly picks a loadscreen is that it deletes your original loadscreen.jpg file (after having backed it up), then runs through all of the load*.jpg files in Resources\Loadscreen and, for each one, picks a random number from 0-32767 ("%Random%"). If the random number for that particular file is less than 1000 (~1/33 odds), it makes it your loadscreen. If it runs through the whole list of files and none of them ended up getting the 1/33 random chance, it runs through them again until one does.

Pretty simplistic, but it gets the job done.
Reply With Quote
  #6  
Old 07-18-2009, 01:00 PM
vales
Discordant
 
Join Date: May 2006
Posts: 458
Default

Math makes my head hurt and Baby Jesus cry.
Reply With Quote
  #7  
Old 07-20-2009, 11:16 AM
provocating's Avatar
provocating
Demi-God
 
Join Date: Nov 2007
Posts: 2,175
Default

These are badass, love them. I cannot wait till I get them installed. Want me to host a rar of them for you ? I am pretty sure I have unlimited bandwidth and unlimited storage space on my server account.
Reply With Quote
Reply

Thread Tools
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

   

All times are GMT -4. The time now is 01:06 PM.


 

Everquest is a registered trademark of Daybreak Game Company LLC.
EQEmulator is not associated or affiliated in any way with Daybreak Game Company LLC.
Except where otherwise noted, this site is licensed under a Creative Commons License.
       
Powered by vBulletin®, Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
Template by Bluepearl Design and vBulletin Templates - Ver3.3